Arduino UNO R4 WiFiで現在時刻をNTPサーバーから取得してLEDマトリクスにスクロール表示させる方法

/* 作品名：UNO_R4_WiFi_RTC_GetTime */
/* 作成者：せでぃあ　https://cediablog.com */
/* NTPサーバーから現在時刻を取得してLEDマトリクスに表示させる */

// RTCライブラリをインクルードする
#include "RTC.h"

// WiFiS3ライブラリをインクルードする
#include "WiFiS3.h"
// WiFiUdpクラスをインクルードする
#include "WiFiUdp.h"
// NTPClientライブラリをインクルードする
#include "NTPClient.h"

// arduino_secretsをインクルードする
#include "arduino_secrets.h"


// ArduinoGraphicsライブラリをインクルードする
#include "ArduinoGraphics.h"
// Arduino_LED_Matrixライブラリをインクルードする
#include "Arduino_LED_Matrix.h"

// connect_animationをインクルードする
#include "connect_animation.h"

// 現在時刻のオフセット(日本時間は標準時間+9時間)
#define timeZoneOffsetHours 9
// NTPサーバーのアドレス
#define ntpserver "ntp.nict.jp"

// ネットワークのSSIDとパスワードを定義する
char ssid[] = SECRET_SSID;
char pass[] = SECRET_PASS;

// WiFiUDPオブジェクトを作成
WiFiUDP ntpUdp;

// NTPClientオブジェクトを作成
NTPClient timeClient(ntpUdp, ntpserver, timeZoneOffsetHours * 3600);

// マトリックスパネルのオブジェクトを作成する
ArduinoLEDMatrix matrix;

//日時を文字列として格納するための変数
char realtime[100];

// 接続成功時にLEDマトリクスに表示するマークを定義"OK"
const uint32_t connect_ok[] = {
  0x31149285,
  0x48588588,
  0x54492311,
};

// 接続失敗時にLEDマトリクスに表示するマークを定義"NG"
const uint32_t connect_ng[] = {
  0x85fc50a5,
  0xa509579,
  0x518d185f,
};

// NTP接続時にLEDマトリクスに表示するマークを定義"NTP"
const uint32_t connect_ntp[] = {
  0x97792,
  0x5d27b249,
  0x24924000,
};

// NTPデータ取得後にLEDマトリクスに表示するマークを定義"GET"
const uint32_t get_ntp[] = {
  0xf7784,
  0x2872b729,
  0x42f72000,
};

void setup() {
  // シリアル通信を開始する
  Serial.begin(9600);

  // LEDマトリクス動作を開始する
  matrix.begin();

  // RTC時刻の初期化
  RTC.begin();

  // WiFiネットワークに接続されているかチェックする
  if (WiFi.status() != WL_CONNECTED) {
    // シリアルモニタに接続中コメントとSSIDを表示
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // ネットワークに接続する
    WiFi.begin(ssid, pass);
    // 接続中マトリックスアニメーション表示を読み出す
    matrix.loadSequence(connect_animation);
    // 接続中マトリックスアニメーション表示を有効
    matrix.play(true);
    // 3秒待つ
    delay(3000);

    // WiFiネットワークに接続できたときの処理
    if (WiFi.status() == WL_CONNECTED) {
      // 接続に成功したことをシリアルモニタに表示する
      Serial.println("Connected to wifi");
      // マトリックスパネルにOKマークを表示する
      matrix.loadFrame(connect_ok);
      // 1秒待つ
      delay(1000);
      // サーバーに接続中であることシリアルモニタに表示する
      Serial.println("Starting connection to server...");
      // NTPClientを開始
      timeClient.begin();
      // NTPClientを更新
      timeClient.update();
      // マトリックスパネルにNTPマークを表示する
      matrix.loadFrame(connect_ntp);
      // 1秒待つ
      delay(1000);

      // NTPサーバーから取得した日本のエポック秒(UNIX時間)をRTC時刻にセット
      RTCTime timeToSet = RTCTime(timeClient.getEpochTime());
      RTC.setTime(timeToSet);
      // ネットワークから切断する
      WiFi.disconnect();
      // マトリックスパネルにGETマークを表示する
      matrix.loadFrame(get_ntp);
      // 1秒待つ
      delay(1000);

    } else {
      // 接続に失敗したことをシリアルモニタに表示する
      Serial.println("Disonnected to wifi");
      // マトリックスパネルにNGマークを表示する
      matrix.loadFrame(connect_ng);
    }
  }
}

void loop() {

  // 時刻の格納先
  RTCTime currentTime;
  // RTCから時計データを取得
  RTC.getTime(currentTime);

  // 曜日文字列の格納先
  char str_dayofweek[6] = "(XXX)";

  // RTCから入手した曜日データにより表示内容を振り分ける
  // 0:日曜日～6：土曜日
  switch ((int)currentTime.getDayOfWeek()) {
    case 0:
      strcpy(str_dayofweek, "(SUN)");
      break;
    case 1:
      strcpy(str_dayofweek, "(MON)");
      break;
    case 2:
      strcpy(str_dayofweek, "(TUE)");
      break;
    case 3:
      strcpy(str_dayofweek, "(WED)");
      break;
    case 4:
      strcpy(str_dayofweek, "(THU)");
      break;
    case 5:
      strcpy(str_dayofweek, "(FRI)");
      break;
    case 6:
      strcpy(str_dayofweek, "(SAT)");
      ;
      break;
  }

  // 年月日、曜日、時間データを文字列｢realtime｣に格納
  sprintf(realtime, "     %04d/%02d/%02d%s %02d:%02d:%02d     ",
          currentTime.getYear(),
          Month2int(currentTime.getMonth()),
          currentTime.getDayOfMonth(),
          str_dayofweek,
          currentTime.getHour(),
          currentTime.getMinutes(),
          currentTime.getSeconds());

  // LEDマトリクスに表示する文字列をシリアルモニタに表示
  Serial.print("JPN time = ");
  Serial.println(realtime);

  // LEDマトリクス表示を開始
  matrix.beginDraw();

  matrix.stroke(0xFFFFFFFF);
  // テキストスクロール速度を指定(msec)
  matrix.textScrollSpeed(50);
  // 使用するフォントを設定
  matrix.textFont(Font_5x7);
  // テキスト描画を開始
  matrix.beginText(0, 1, 0xFFFFFF);
  // テキスト表示を行う
  matrix.print(realtime);
  // 表示を終了し、スクロール表示方向を指定
  matrix.endText(SCROLL_LEFT);
  // LEDマトリクス表示を終了
  matrix.endDraw();
}

#define SECRET_SSID "接続するネットワークSSID"
#define SECRET_PASS "接続するネットワークパスワード"

const uint32_t connect_animation[][4] = {
	{
		0x0,
		0x0,
		0x60060,
		66
	},
	{
		0x0,
		0xf01,
		0x8060060,
		66
	},
	{
		0x1f,
		0x82044f21,
		0x8060060,
		66
	},
	{
		0x3fc4029f,
		0x92044f21,
		0x8060060,
		66
	}
};

// RTCライブラリをインクルードする
#include "RTC.h"

// WiFiS3ライブラリをインクルードする
#include "WiFiS3.h"
// WiFiUdpクラスをインクルードする
#include "WiFiUdp.h"

// NTPClientライブラリをインクルードする
#include "NTPClient.h"

// ArduinoGraphicsライブラリをインクルードする
#include "ArduinoGraphics.h"
// Arduino_LED_Matrixライブラリをインクルードする
#include "Arduino_LED_Matrix.h"

// arduino_secretsをインクルードする
#include "arduino_secrets.h"

// connect_animationをインクルードする
#include "connect_animation.h"

  // WiFiネットワークに接続されているかチェックする
  if (WiFi.status() != WL_CONNECTED) {